Déc 15 2012

Script de Sauvegarde d’un NAS ou Serveur Windows Distant

Publié par à 3:37 sous Sauvegarde




robocopy est fourni dans le kit de ressources de Windows 2003 Serveur ou nativement dans Windows 2008 Serveur.
Robocopy permet de copier et même de synchroniser des données d’un serveur (ou un NAS) vers un autre serveur Windows.
La synchronisation prend peu de bande passante et peut être employée pour sauvegarder des données sur un lien réseau lent.
 
Voici un script DOS qui synchronise les données depuis les dossiers partagés d’un serveur distant vers un serveur local. Le serveur local peut ensuite être sauvegardé avec tout logiciel de sauvegarde.
Je l’utilise pour des sites distants avec des fichiers hébergés sur NAS.
 

@echo off
CLS

SETLOCAL ENABLEDELAYEDEXPANSION
set REMOTE_NAS=192.168.1.250
set LOCAL_DIRECTORY=C:\Copy
set EXCLUDE_DIR="Shares Not To be Backed Up"

rem Go through server/NAS shares
for /F "tokens=1 delims=" %%K in ^
  ('net view %REMOTE_NAS%^|findstr Disk^|findstr /V %EXCLUDE_DIR%') do (
  set SHARELINE=%%K
  set SHARELINE=!SHARELINE:Disk=#!
  
  for /F "tokens=1 delims=#" %%S in ("!SHARELINE!") do (
    set SHARE=%%S
    echo Processing \\%REMOTE_NAS%\!SHARE!...
    robocopy "\\%REMOTE_NAS%\!SHARE!" "%LOCAL_DIRECTORY%\!SHARE!" ^
    /XF *.avi Thumbs.db /XD Temp* /E /COPY:DAT /R:0 /W:1 /NP
  )
)

 
Enregistrez avec une extension BAT, adaptez les différents paramètres et créez une tâche planifiée à exécuter chaque nuit.


One response so far

Une Réponse à “Script de Sauvegarde d’un NAS ou Serveur Windows Distant”

  1. Steveon 24 Mai 2015 at 3:27

    Bonjour,
    Merci pour votre article.
    Je suis intéressé par ce genre de script, mais un peu dans le sens inverse. Je suis administrateur ERP dans une Entreprise et j’ai demandé au Sys Admin d’effectuer une sauvegarde d’un répertoire spécifique tous les jours, vers un NAS sur un délai de 1 semaine (exemple vers un répertoire j1 pour lundi,j2 pour mardi,j3 …. j7). Lorsque le lundi suivant arrive, le répertoire J1 sera écrasé (ou effacé puis recréé selon le cas) et ainsi de suite.
    Quelqu’un aurait-il une ébauche svp ?
    Merci

    PS : Serveur MS Windows 2012

Comments RSS

Leave a Reply